***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 09, 2026                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P4FL16A-AU  A K 
.param
+vc0 = 2.106e-9 	vc1 = 1.500e-10		vc2 = 6.000e-1		vc3 = 3.075e-14		vc4 = 1.749e-1
+tc1 = 3.081e-2		tc2 = 1.711e-2		tc3 = 6.701e-2		tc4 = 8.861e-2
d1  A A1 zener
g1 A1 A value = {irexp(v(A1,A))}
v1 A1 K1 0
e1 K1 K value = {rbv(i(v1))}
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func rbv(i) {2.673e-1*min(i,0)}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.069e-14	  n = 1.016		 rs = 8.568e-3
+ibv = 1.000e-3	        nbv = 1.000	         bv = 18.75
+ikf = 4.497
***** capacitance parameter *****
+cjo = 7.918e-10	  m = 3.355e-1		 vj = 6.452e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		 eg = 1.115	        xti = 3
+trs1 = 2.000e-3       tikf = 1.000e-2
+tbv1 = 7.970e-4       tbv2 = -4.086e-8	
.ends P4FL16A-AU
*$
